| # Fake the existence of programs that GNU maintainers use. -*- Autoconf -*- |
| |
| # Copyright (C) 1997-2018 Free Software Foundation, Inc. |
| # |
| # This file is free software; the Free Software Foundation |
| # gives unlimited permission to copy and/or distribute it, |
| # with or without modifications, as long as this notice is preserved. |
| |
| # AM_MISSING_PROG(NAME, PROGRAM) |
| # ------------------------------ |
| AC_DEFUN([AM_MISSING_PROG], |
| [AC_REQUIRE([AM_MISSING_HAS_RUN]) |
| $1=${$1-"${am_missing_run}$2"} |
| AC_SUBST($1)]) |
| |
| # AM_MISSING_HAS_RUN |
| # ------------------ |
| # Define MISSING if not defined so far and test if it is modern enough. |
| # If it is, set am_missing_run to use it, otherwise, to nothing. |
| AC_DEFUN([AM_MISSING_HAS_RUN], |
| [AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl |
| AC_REQUIRE_AUX_FILE([missing])dnl |
| if test x"${MISSING+set}" != xset; then |
| case $am_aux_dir in |
| *\ * | *\ *) |
| MISSING="\${SHELL} \"$am_aux_dir/missing\"" ;; |
| *) |
| MISSING="\${SHELL} $am_aux_dir/missing" ;; |
| esac |
| fi |
| # Use eval to expand $SHELL |
| if eval "$MISSING --is-lightweight"; then |
| am_missing_run="$MISSING " |
| else |
| am_missing_run= |
| AC_MSG_WARN(['missing' script is too old or missing]) |
| fi |
| ]) |
