blob: b2463c72b7f54e692fe49286bcad9ee96f8e3f62 [file] [log] [blame]
# Sed commands to finish translating the Unix BFD Makefile into MPW syntax.
# Whack out unused host and target define bits.
# Fix pathnames to include directories.
/^INCDIR = /s/^INCDIR = .*$/INCDIR = "{topsrcdir}"include/
/^CSEARCH = /s/$/ -i "{INCDIR}":mpw: -i ::extra-include:/
# Comment out setting of vars, configure script will add these itself.
/^WORDSIZE =/s/^/#/
# /^ALL_BACKENDS/s/^/#/
# Remove extra, useless, "all".
/^all \\Option-f _oldest/,/^$/d
# Remove the Makefile rebuild rule.
/^Makefile /,/--recheck/d
# Don't do any recursive subdir stuff.
/ subdir_do/s/{MAKE}/null-command/
# Add explicit srcdir paths to special files.
/config.bfd/s/ config.bfd/ "{s}"config.bfd/g
/targmatch.sed/s/ targmatch.sed/ "{s}"targmatch.sed/g
# Point at include files that are always in the objdir.
# Removing duplicates is cool but presently unnecessary,
# so whack this out.
/^ofiles \\Option-f/,/^$/d
/ofiles/s/{OFILES} ofiles/{OFILES}/
/echo ofiles = /d
/cat ofiles/s/`cat ofiles`/{OFILES}/
# No corefile support.
# No PIC foolery in this environment.
/^{OFILES} \\Option-f stamp-picdir/,/^$/d
# Remove the pic trickery from the default build rule.
/^\.c\.o \\Option-f /,/End If/c\
.c.o \\Option-f .c
# MPW Make doesn't know about $<.
/"{o}"targets.c.o \\Option-f "{s}"targets.c Makefile/,/^$/c\
"{o}"targets.c.o \\Option-f "{s}"targets.c Makefile\
{CC} @DASH_C_FLAG@ {ALL_CFLAGS} {TDEFAULTS} "{s}"targets.c -o "{o}"targets.c.o
/"{o}"archures.c.o \\Option-f "{s}"archures.c Makefile/,/^$/c\
"{o}"archures.c.o \\Option-f "{s}"archures.c Makefile\
{CC} @DASH_C_FLAG@ {ALL_CFLAGS} {TDEFAULTS} "{s}"archures.c -o "{o}"archures.c.o
# Remove the .h rebuilding rules, we don't currently have a doc subdir,
# or a way to build the prototype-hacking tool that's in it.
/^"{srcdir}"bfd-in2.h \\Option-f /,/^$/d
/^"{srcdir}"libbfd.h \\Option-f /,/^$/d
/^"{srcdir}"libcoff.h \\Option-f /,/^$/d