| ! { dg-do compile } |
| ! { dg-options "-std=legacy" } |
| *> \brief \b CGEMM |
| * |
| * =========== DOCUMENTATION =========== |
| * |
| * Online html documentation available at |
| * http://www.netlib.org/lapack/explore-html/ |
| * |
| * Definition: |
| * =========== |
| * |
| * SUBROUTINE CGEMM(TRANSA,TRANSB,M,N,K,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
| * |
| * .. Scalar Arguments .. |
| * COMPLEX ALPHA,BETA |
| * INTEGER K,LDA,LDB,LDC,M,N |
| * CHARACTER TRANSA,TRANSB |
| * .. |
| * .. Array Arguments .. |
| * COMPLEX A(LDA,*),B(LDB,*),C(LDC,*) |
| * .. |
| * |
| * |
| *> \par Purpose: |
| * ============= |
| *> |
| *> \verbatim |
| *> |
| *> CGEMM performs one of the matrix-matrix operations |
| *> |
| *> C := alpha*op( A )*op( B ) + beta*C, |
| *> |
| *> where op( X ) is one of |
| *> |
| *> op( X ) = X or op( X ) = X**T or op( X ) = X**H, |
| *> |
| *> alpha and beta are scalars, and A, B and C are matrices, with op( A ) |
| *> an m by k matrix, op( B ) a k by n matrix and C an m by n matrix. |
| *> \endverbatim |
| * |
| * Arguments: |
| * ========== |
| * |
| *> \param[in] TRANSA |
| *> \verbatim |
| *> TRANSA is CHARACTER*1 |
| *> On entry, TRANSA specifies the form of op( A ) to be used in |
| *> the matrix multiplication as follows: |
| *> |
| *> TRANSA = 'N' or 'n', op( A ) = A. |
| *> |
| *> TRANSA = 'T' or 't', op( A ) = A**T. |
| *> |
| *> TRANSA = 'C' or 'c', op( A ) = A**H. |
| *> \endverbatim |
| *> |
| *> \param[in] TRANSB |
| *> \verbatim |
| *> TRANSB is CHARACTER*1 |
| *> On entry, TRANSB specifies the form of op( B ) to be used in |
| *> the matrix multiplication as follows: |
| *> |
| *> TRANSB = 'N' or 'n', op( B ) = B. |
| *> |
| *> TRANSB = 'T' or 't', op( B ) = B**T. |
| *> |
| *> TRANSB = 'C' or 'c', op( B ) = B**H. |
| *> \endverbatim |
| *> |
| *> \param[in] M |
| *> \verbatim |
| *> M is INTEGER |
| *> On entry, M specifies the number of rows of the matrix |
| *> op( A ) and of the matrix C. M must be at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] N |
| *> \verbatim |
| *> N is INTEGER |
| *> On entry, N specifies the number of columns of the matrix |
| *> op( B ) and the number of columns of the matrix C. N must be |
| *> at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] K |
| *> \verbatim |
| *> K is INTEGER |
| *> On entry, K specifies the number of columns of the matrix |
| *> op( A ) and the number of rows of the matrix op( B ). K must |
| *> be at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] ALPHA |
| *> \verbatim |
| *> ALPHA is COMPLEX |
| *> On entry, ALPHA specifies the scalar alpha. |
| *> \endverbatim |
| *> |
| *> \param[in] A |
| *> \verbatim |
| *> A is COMPLEX array, dimension ( LDA, ka ), where ka is |
| *> k when TRANSA = 'N' or 'n', and is m otherwise. |
| *> Before entry with TRANSA = 'N' or 'n', the leading m by k |
| *> part of the array A must contain the matrix A, otherwise |
| *> the leading k by m part of the array A must contain the |
| *> matrix A. |
| *> \endverbatim |
| *> |
| *> \param[in] LDA |
| *> \verbatim |
| *> LDA is INTEGER |
| *> On entry, LDA specifies the first dimension of A as declared |
| *> in the calling (sub) program. When TRANSA = 'N' or 'n' then |
| *> LDA must be at least max( 1, m ), otherwise LDA must be at |
| *> least max( 1, k ). |
| *> \endverbatim |
| *> |
| *> \param[in] B |
| *> \verbatim |
| *> B is COMPLEX array, dimension ( LDB, kb ), where kb is |
| *> n when TRANSB = 'N' or 'n', and is k otherwise. |
| *> Before entry with TRANSB = 'N' or 'n', the leading k by n |
| *> part of the array B must contain the matrix B, otherwise |
| *> the leading n by k part of the array B must contain the |
| *> matrix B. |
| *> \endverbatim |
| *> |
| *> \param[in] LDB |
| *> \verbatim |
| *> LDB is INTEGER |
| *> On entry, LDB specifies the first dimension of B as declared |
| *> in the calling (sub) program. When TRANSB = 'N' or 'n' then |
| *> LDB must be at least max( 1, k ), otherwise LDB must be at |
| *> least max( 1, n ). |
| *> \endverbatim |
| *> |
| *> \param[in] BETA |
| *> \verbatim |
| *> BETA is COMPLEX |
| *> On entry, BETA specifies the scalar beta. When BETA is |
| *> supplied as zero then C need not be set on input. |
| *> \endverbatim |
| *> |
| *> \param[in,out] C |
| *> \verbatim |
| *> C is COMPLEX array, dimension ( LDC, N ) |
| *> Before entry, the leading m by n part of the array C must |
| *> contain the matrix C, except when beta is zero, in which |
| *> case C need not be set on entry. |
| *> On exit, the array C is overwritten by the m by n matrix |
| *> ( alpha*op( A )*op( B ) + beta*C ). |
| *> \endverbatim |
| *> |
| *> \param[in] LDC |
| *> \verbatim |
| *> LDC is INTEGER |
| *> On entry, LDC specifies the first dimension of C as declared |
| *> in the calling (sub) program. LDC must be at least |
| *> max( 1, m ). |
| *> \endverbatim |
| * |
| * Authors: |
| * ======== |
| * |
| *> \author Univ. of Tennessee |
| *> \author Univ. of California Berkeley |
| *> \author Univ. of Colorado Denver |
| *> \author NAG Ltd. |
| * |
| *> \date December 2016 |
| * |
| *> \ingroup complex_blas_level3 |
| * |
| *> \par Further Details: |
| * ===================== |
| *> |
| *> \verbatim |
| *> |
| *> Level 3 Blas routine. |
| *> |
| *> -- Written on 8-February-1989. |
| *> Jack Dongarra, Argonne National Laboratory. |
| *> Iain Duff, AERE Harwell. |
| *> Jeremy Du Croz, Numerical Algorithms Group Ltd. |
| *> Sven Hammarling, Numerical Algorithms Group Ltd. |
| *> \endverbatim |
| *> |
| * ===================================================================== |
| SUBROUTINE CGEMM(TRANSA,TRANSB,M,N,K,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
| * |
| * -- Reference BLAS level3 routine (version 3.7.0) -- |
| * -- Reference BLAS is a software package provided by Univ. of Tennessee, -- |
| * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
| * December 2016 |
| * |
| * .. Scalar Arguments .. |
| COMPLEX ALPHA,BETA |
| INTEGER K,LDA,LDB,LDC,M,N |
| CHARACTER TRANSA,TRANSB |
| * .. |
| * .. Array Arguments .. |
| COMPLEX A(LDA,*),B(LDB,*),C(LDC,*) |
| * .. |
| * |
| * ===================================================================== |
| * |
| * .. External Functions .. |
| LOGICAL LSAME |
| EXTERNAL LSAME |
| * .. |
| * .. External Subroutines .. |
| EXTERNAL XERBLA |
| * .. |
| * .. Intrinsic Functions .. |
| INTRINSIC CONJG,MAX |
| * .. |
| * .. Local Scalars .. |
| COMPLEX TEMP |
| INTEGER I,INFO,J,L,NCOLA,NROWA,NROWB |
| LOGICAL CONJA,CONJB,NOTA,NOTB |
| * .. |
| * .. Parameters .. |
| COMPLEX ONE |
| PARAMETER (ONE= (1.0E+0,0.0E+0)) |
| COMPLEX ZERO |
| PARAMETER (ZERO= (0.0E+0,0.0E+0)) |
| * .. |
| * |
| * Set NOTA and NOTB as true if A and B respectively are not |
| * conjugated or transposed, set CONJA and CONJB as true if A and |
| * B respectively are to be transposed but not conjugated and set |
| * NROWA, NCOLA and NROWB as the number of rows and columns of A |
| * and the number of rows of B respectively. |
| * |
| NOTA = LSAME(TRANSA,'N') |
| NOTB = LSAME(TRANSB,'N') |
| CONJA = LSAME(TRANSA,'C') |
| CONJB = LSAME(TRANSB,'C') |
| IF (NOTA) THEN |
| NROWA = M |
| NCOLA = K |
| ELSE |
| NROWA = K |
| NCOLA = M |
| END IF |
| IF (NOTB) THEN |
| NROWB = K |
| ELSE |
| NROWB = N |
| END IF |
| * |
| * Test the input parameters. |
| * |
| INFO = 0 |
| IF ((.NOT.NOTA) .AND. (.NOT.CONJA) .AND. |
| + (.NOT.LSAME(TRANSA,'T'))) THEN |
| INFO = 1 |
| ELSE IF ((.NOT.NOTB) .AND. (.NOT.CONJB) .AND. |
| + (.NOT.LSAME(TRANSB,'T'))) THEN |
| INFO = 2 |
| ELSE IF (M.LT.0) THEN |
| INFO = 3 |
| ELSE IF (N.LT.0) THEN |
| INFO = 4 |
| ELSE IF (K.LT.0) THEN |
| INFO = 5 |
| ELSE IF (LDA.LT.MAX(1,NROWA)) THEN |
| INFO = 8 |
| ELSE IF (LDB.LT.MAX(1,NROWB)) THEN |
| INFO = 10 |
| ELSE IF (LDC.LT.MAX(1,M)) THEN |
| INFO = 13 |
| END IF |
| IF (INFO.NE.0) THEN |
| CALL XERBLA('CGEMM ',INFO) |
| RETURN |
| END IF |
| * |
| * Quick return if possible. |
| * |
| IF ((M.EQ.0) .OR. (N.EQ.0) .OR. |
| + (((ALPHA.EQ.ZERO).OR. (K.EQ.0)).AND. (BETA.EQ.ONE))) RETURN |
| * |
| * And when alpha.eq.zero. |
| * |
| IF (ALPHA.EQ.ZERO) THEN |
| IF (BETA.EQ.ZERO) THEN |
| DO 20 J = 1,N |
| DO 10 I = 1,M |
| C(I,J) = ZERO |
| 10 CONTINUE |
| 20 CONTINUE |
| ELSE |
| DO 40 J = 1,N |
| DO 30 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 30 CONTINUE |
| 40 CONTINUE |
| END IF |
| RETURN |
| END IF |
| * |
| * Start the operations. |
| * |
| IF (NOTB) THEN |
| IF (NOTA) THEN |
| * |
| * Form C := alpha*A*B + beta*C. |
| * |
| DO 90 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 50 I = 1,M |
| C(I,J) = ZERO |
| 50 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 60 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 60 CONTINUE |
| END IF |
| DO 80 L = 1,K |
| TEMP = ALPHA*B(L,J) |
| DO 70 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 70 CONTINUE |
| 80 CONTINUE |
| 90 CONTINUE |
| ELSE IF (CONJA) THEN |
| * |
| * Form C := alpha*A**H*B + beta*C. |
| * |
| DO 120 J = 1,N |
| DO 110 I = 1,M |
| TEMP = ZERO |
| DO 100 L = 1,K |
| TEMP = TEMP + CONJG(A(L,I))*B(L,J) |
| 100 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 110 CONTINUE |
| 120 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**T*B + beta*C |
| * |
| DO 150 J = 1,N |
| DO 140 I = 1,M |
| TEMP = ZERO |
| DO 130 L = 1,K |
| TEMP = TEMP + A(L,I)*B(L,J) |
| 130 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 140 CONTINUE |
| 150 CONTINUE |
| END IF |
| ELSE IF (NOTA) THEN |
| IF (CONJB) THEN |
| * |
| * Form C := alpha*A*B**H + beta*C. |
| * |
| DO 200 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 160 I = 1,M |
| C(I,J) = ZERO |
| 160 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 170 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 170 CONTINUE |
| END IF |
| DO 190 L = 1,K |
| TEMP = ALPHA*CONJG(B(J,L)) |
| DO 180 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 180 CONTINUE |
| 190 CONTINUE |
| 200 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A*B**T + beta*C |
| * |
| DO 250 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 210 I = 1,M |
| C(I,J) = ZERO |
| 210 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 220 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 220 CONTINUE |
| END IF |
| DO 240 L = 1,K |
| TEMP = ALPHA*B(J,L) |
| DO 230 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 230 CONTINUE |
| 240 CONTINUE |
| 250 CONTINUE |
| END IF |
| ELSE IF (CONJA) THEN |
| IF (CONJB) THEN |
| * |
| * Form C := alpha*A**H*B**H + beta*C. |
| * |
| DO 280 J = 1,N |
| DO 270 I = 1,M |
| TEMP = ZERO |
| DO 260 L = 1,K |
| TEMP = TEMP + CONJG(A(L,I))*CONJG(B(J,L)) |
| 260 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 270 CONTINUE |
| 280 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**H*B**T + beta*C |
| * |
| DO 310 J = 1,N |
| DO 300 I = 1,M |
| TEMP = ZERO |
| DO 290 L = 1,K |
| TEMP = TEMP + CONJG(A(L,I))*B(J,L) |
| 290 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 300 CONTINUE |
| 310 CONTINUE |
| END IF |
| ELSE |
| IF (CONJB) THEN |
| * |
| * Form C := alpha*A**T*B**H + beta*C |
| * |
| DO 340 J = 1,N |
| DO 330 I = 1,M |
| TEMP = ZERO |
| DO 320 L = 1,K |
| TEMP = TEMP + A(L,I)*CONJG(B(J,L)) |
| 320 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 330 CONTINUE |
| 340 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**T*B**T + beta*C |
| * |
| DO 370 J = 1,N |
| DO 360 I = 1,M |
| TEMP = ZERO |
| DO 350 L = 1,K |
| TEMP = TEMP + A(L,I)*B(J,L) |
| 350 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 360 CONTINUE |
| 370 CONTINUE |
| END IF |
| END IF |
| * |
| RETURN |
| * |
| * End of CGEMM . |
| * |
| END |
| |
| *> \brief \b LSAME |
| * |
| * =========== DOCUMENTATION =========== |
| * |
| * Online html documentation available at |
| * http://www.netlib.org/lapack/explore-html/ |
| * |
| * Definition: |
| * =========== |
| * |
| * LOGICAL FUNCTION LSAME(CA,CB) |
| * |
| * .. Scalar Arguments .. |
| * CHARACTER CA,CB |
| * .. |
| * |
| * |
| *> \par Purpose: |
| * ============= |
| *> |
| *> \verbatim |
| *> |
| *> LSAME returns .TRUE. if CA is the same letter as CB regardless of |
| *> case. |
| *> \endverbatim |
| * |
| * Arguments: |
| * ========== |
| * |
| *> \param[in] CA |
| *> \verbatim |
| *> CA is CHARACTER*1 |
| *> \endverbatim |
| *> |
| *> \param[in] CB |
| *> \verbatim |
| *> CB is CHARACTER*1 |
| *> CA and CB specify the single characters to be compared. |
| *> \endverbatim |
| * |
| * Authors: |
| * ======== |
| * |
| *> \author Univ. of Tennessee |
| *> \author Univ. of California Berkeley |
| *> \author Univ. of Colorado Denver |
| *> \author NAG Ltd. |
| * |
| *> \date December 2016 |
| * |
| *> \ingroup aux_blas |
| * |
| * ===================================================================== |
| LOGICAL FUNCTION LSAME(CA,CB) |
| * |
| * -- Reference BLAS level1 routine (version 3.1) -- |
| * -- Reference BLAS is a software package provided by Univ. of Tennessee, -- |
| * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
| * December 2016 |
| * |
| * .. Scalar Arguments .. |
| CHARACTER CA,CB |
| * .. |
| * |
| * ===================================================================== |
| * |
| * .. Intrinsic Functions .. |
| INTRINSIC ICHAR |
| * .. |
| * .. Local Scalars .. |
| INTEGER INTA,INTB,ZCODE |
| * .. |
| * |
| * Test if the characters are equal |
| * |
| LSAME = CA .EQ. CB |
| IF (LSAME) RETURN |
| * |
| * Now test for equivalence if both characters are alphabetic. |
| * |
| ZCODE = ICHAR('Z') |
| * |
| * Use 'Z' rather than 'A' so that ASCII can be detected on Prime |
| * machines, on which ICHAR returns a value with bit 8 set. |
| * ICHAR('A') on Prime machines returns 193 which is the same as |
| * ICHAR('A') on an EBCDIC machine. |
| * |
| INTA = ICHAR(CA) |
| INTB = ICHAR(CB) |
| * |
| IF (ZCODE.EQ.90 .OR. ZCODE.EQ.122) THEN |
| * |
| * ASCII is assumed - ZCODE is the ASCII code of either lower or |
| * upper case 'Z'. |
| * |
| IF (INTA.GE.97 .AND. INTA.LE.122) INTA = INTA - 32 |
| IF (INTB.GE.97 .AND. INTB.LE.122) INTB = INTB - 32 |
| * |
| ELSE IF (ZCODE.EQ.233 .OR. ZCODE.EQ.169) THEN |
| * |
| * EBCDIC is assumed - ZCODE is the EBCDIC code of either lower or |
| * upper case 'Z'. |
| * |
| IF (INTA.GE.129 .AND. INTA.LE.137 .OR. |
| + INTA.GE.145 .AND. INTA.LE.153 .OR. |
| + INTA.GE.162 .AND. INTA.LE.169) INTA = INTA + 64 |
| IF (INTB.GE.129 .AND. INTB.LE.137 .OR. |
| + INTB.GE.145 .AND. INTB.LE.153 .OR. |
| + INTB.GE.162 .AND. INTB.LE.169) INTB = INTB + 64 |
| * |
| ELSE IF (ZCODE.EQ.218 .OR. ZCODE.EQ.250) THEN |
| * |
| * ASCII is assumed, on Prime machines - ZCODE is the ASCII code |
| * plus 128 of either lower or upper case 'Z'. |
| * |
| IF (INTA.GE.225 .AND. INTA.LE.250) INTA = INTA - 32 |
| IF (INTB.GE.225 .AND. INTB.LE.250) INTB = INTB - 32 |
| END IF |
| LSAME = INTA .EQ. INTB |
| * |
| * RETURN |
| * |
| * End of LSAME |
| * |
| END |
| |
| *> \brief \b XERBLA |
| * |
| * =========== DOCUMENTATION =========== |
| * |
| * Online html documentation available at |
| * http://www.netlib.org/lapack/explore-html/ |
| * |
| * Definition: |
| * =========== |
| * |
| * SUBROUTINE XERBLA( SRNAME, INFO ) |
| * |
| * .. Scalar Arguments .. |
| * CHARACTER*(*) SRNAME |
| * INTEGER INFO |
| * .. |
| * |
| * |
| *> \par Purpose: |
| * ============= |
| *> |
| *> \verbatim |
| *> |
| *> XERBLA is an error handler for the LAPACK routines. |
| *> It is called by an LAPACK routine if an input parameter has an |
| *> invalid value. A message is printed and execution stops. |
| *> |
| *> Installers may consider modifying the STOP statement in order to |
| *> call system-specific exception-handling facilities. |
| *> \endverbatim |
| * |
| * Arguments: |
| * ========== |
| * |
| *> \param[in] SRNAME |
| *> \verbatim |
| *> SRNAME is CHARACTER*(*) |
| *> The name of the routine which called XERBLA. |
| *> \endverbatim |
| *> |
| *> \param[in] INFO |
| *> \verbatim |
| *> INFO is INTEGER |
| *> The position of the invalid parameter in the parameter list |
| *> of the calling routine. |
| *> \endverbatim |
| * |
| * Authors: |
| * ======== |
| * |
| *> \author Univ. of Tennessee |
| *> \author Univ. of California Berkeley |
| *> \author Univ. of Colorado Denver |
| *> \author NAG Ltd. |
| * |
| *> \date December 2016 |
| * |
| *> \ingroup aux_blas |
| * |
| * ===================================================================== |
| SUBROUTINE XERBLA( SRNAME, INFO ) |
| * |
| * -- Reference BLAS level1 routine (version 3.7.0) -- |
| * -- Reference BLAS is a software package provided by Univ. of Tennessee, -- |
| * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
| * December 2016 |
| * |
| * .. Scalar Arguments .. |
| CHARACTER*(*) SRNAME |
| INTEGER INFO |
| * .. |
| * |
| * ===================================================================== |
| * |
| * .. Intrinsic Functions .. |
| INTRINSIC LEN_TRIM |
| * .. |
| * .. Executable Statements .. |
| * |
| WRITE( *, FMT = 9999 )SRNAME( 1:LEN_TRIM( SRNAME ) ), INFO |
| * |
| STOP |
| * |
| 9999 FORMAT( ' ** On entry to ', A, ' parameter number ', I2, ' had ', |
| $ 'an illegal value' ) |
| * |
| * End of XERBLA |
| * |
| END |
| |
| *> \brief \b SGEMM |
| * |
| * =========== DOCUMENTATION =========== |
| * |
| * Online html documentation available at |
| * http://www.netlib.org/lapack/explore-html/ |
| * |
| * Definition: |
| * =========== |
| * |
| * SUBROUTINE SGEMM(TRANSA,TRANSB,M,N,K,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
| * |
| * .. Scalar Arguments .. |
| * REAL ALPHA,BETA |
| * INTEGER K,LDA,LDB,LDC,M,N |
| * CHARACTER TRANSA,TRANSB |
| * .. |
| * .. Array Arguments .. |
| * REAL A(LDA,*),B(LDB,*),C(LDC,*) |
| * .. |
| * |
| * |
| *> \par Purpose: |
| * ============= |
| *> |
| *> \verbatim |
| *> |
| *> SGEMM performs one of the matrix-matrix operations |
| *> |
| *> C := alpha*op( A )*op( B ) + beta*C, |
| *> |
| *> where op( X ) is one of |
| *> |
| *> op( X ) = X or op( X ) = X**T, |
| *> |
| *> alpha and beta are scalars, and A, B and C are matrices, with op( A ) |
| *> an m by k matrix, op( B ) a k by n matrix and C an m by n matrix. |
| *> \endverbatim |
| * |
| * Arguments: |
| * ========== |
| * |
| *> \param[in] TRANSA |
| *> \verbatim |
| *> TRANSA is CHARACTER*1 |
| *> On entry, TRANSA specifies the form of op( A ) to be used in |
| *> the matrix multiplication as follows: |
| *> |
| *> TRANSA = 'N' or 'n', op( A ) = A. |
| *> |
| *> TRANSA = 'T' or 't', op( A ) = A**T. |
| *> |
| *> TRANSA = 'C' or 'c', op( A ) = A**T. |
| *> \endverbatim |
| *> |
| *> \param[in] TRANSB |
| *> \verbatim |
| *> TRANSB is CHARACTER*1 |
| *> On entry, TRANSB specifies the form of op( B ) to be used in |
| *> the matrix multiplication as follows: |
| *> |
| *> TRANSB = 'N' or 'n', op( B ) = B. |
| *> |
| *> TRANSB = 'T' or 't', op( B ) = B**T. |
| *> |
| *> TRANSB = 'C' or 'c', op( B ) = B**T. |
| *> \endverbatim |
| *> |
| *> \param[in] M |
| *> \verbatim |
| *> M is INTEGER |
| *> On entry, M specifies the number of rows of the matrix |
| *> op( A ) and of the matrix C. M must be at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] N |
| *> \verbatim |
| *> N is INTEGER |
| *> On entry, N specifies the number of columns of the matrix |
| *> op( B ) and the number of columns of the matrix C. N must be |
| *> at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] K |
| *> \verbatim |
| *> K is INTEGER |
| *> On entry, K specifies the number of columns of the matrix |
| *> op( A ) and the number of rows of the matrix op( B ). K must |
| *> be at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] ALPHA |
| *> \verbatim |
| *> ALPHA is REAL |
| *> On entry, ALPHA specifies the scalar alpha. |
| *> \endverbatim |
| *> |
| *> \param[in] A |
| *> \verbatim |
| *> A is REAL array, dimension ( LDA, ka ), where ka is |
| *> k when TRANSA = 'N' or 'n', and is m otherwise. |
| *> Before entry with TRANSA = 'N' or 'n', the leading m by k |
| *> part of the array A must contain the matrix A, otherwise |
| *> the leading k by m part of the array A must contain the |
| *> matrix A. |
| *> \endverbatim |
| *> |
| *> \param[in] LDA |
| *> \verbatim |
| *> LDA is INTEGER |
| *> On entry, LDA specifies the first dimension of A as declared |
| *> in the calling (sub) program. When TRANSA = 'N' or 'n' then |
| *> LDA must be at least max( 1, m ), otherwise LDA must be at |
| *> least max( 1, k ). |
| *> \endverbatim |
| *> |
| *> \param[in] B |
| *> \verbatim |
| *> B is REAL array, dimension ( LDB, kb ), where kb is |
| *> n when TRANSB = 'N' or 'n', and is k otherwise. |
| *> Before entry with TRANSB = 'N' or 'n', the leading k by n |
| *> part of the array B must contain the matrix B, otherwise |
| *> the leading n by k part of the array B must contain the |
| *> matrix B. |
| *> \endverbatim |
| *> |
| *> \param[in] LDB |
| *> \verbatim |
| *> LDB is INTEGER |
| *> On entry, LDB specifies the first dimension of B as declared |
| *> in the calling (sub) program. When TRANSB = 'N' or 'n' then |
| *> LDB must be at least max( 1, k ), otherwise LDB must be at |
| *> least max( 1, n ). |
| *> \endverbatim |
| *> |
| *> \param[in] BETA |
| *> \verbatim |
| *> BETA is REAL |
| *> On entry, BETA specifies the scalar beta. When BETA is |
| *> supplied as zero then C need not be set on input. |
| *> \endverbatim |
| *> |
| *> \param[in,out] C |
| *> \verbatim |
| *> C is REAL array, dimension ( LDC, N ) |
| *> Before entry, the leading m by n part of the array C must |
| *> contain the matrix C, except when beta is zero, in which |
| *> case C need not be set on entry. |
| *> On exit, the array C is overwritten by the m by n matrix |
| *> ( alpha*op( A )*op( B ) + beta*C ). |
| *> \endverbatim |
| *> |
| *> \param[in] LDC |
| *> \verbatim |
| *> LDC is INTEGER |
| *> On entry, LDC specifies the first dimension of C as declared |
| *> in the calling (sub) program. LDC must be at least |
| *> max( 1, m ). |
| *> \endverbatim |
| * |
| * Authors: |
| * ======== |
| * |
| *> \author Univ. of Tennessee |
| *> \author Univ. of California Berkeley |
| *> \author Univ. of Colorado Denver |
| *> \author NAG Ltd. |
| * |
| *> \date December 2016 |
| * |
| *> \ingroup single_blas_level3 |
| * |
| *> \par Further Details: |
| * ===================== |
| *> |
| *> \verbatim |
| *> |
| *> Level 3 Blas routine. |
| *> |
| *> -- Written on 8-February-1989. |
| *> Jack Dongarra, Argonne National Laboratory. |
| *> Iain Duff, AERE Harwell. |
| *> Jeremy Du Croz, Numerical Algorithms Group Ltd. |
| *> Sven Hammarling, Numerical Algorithms Group Ltd. |
| *> \endverbatim |
| *> |
| * ===================================================================== |
| SUBROUTINE SGEMM(TRANSA,TRANSB,M,N,K,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
| * |
| * -- Reference BLAS level3 routine (version 3.7.0) -- |
| * -- Reference BLAS is a software package provided by Univ. of Tennessee, -- |
| * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
| * December 2016 |
| * |
| * .. Scalar Arguments .. |
| REAL ALPHA,BETA |
| INTEGER K,LDA,LDB,LDC,M,N |
| CHARACTER TRANSA,TRANSB |
| * .. |
| * .. Array Arguments .. |
| REAL A(LDA,*),B(LDB,*),C(LDC,*) |
| * .. |
| * |
| * ===================================================================== |
| * |
| * .. External Functions .. |
| LOGICAL LSAME |
| EXTERNAL LSAME |
| * .. |
| * .. External Subroutines .. |
| EXTERNAL XERBLA |
| * .. |
| * .. Intrinsic Functions .. |
| INTRINSIC MAX |
| * .. |
| * .. Local Scalars .. |
| REAL TEMP |
| INTEGER I,INFO,J,L,NCOLA,NROWA,NROWB |
| LOGICAL NOTA,NOTB |
| * .. |
| * .. Parameters .. |
| REAL ONE,ZERO |
| PARAMETER (ONE=1.0E+0,ZERO=0.0E+0) |
| * .. |
| * |
| * Set NOTA and NOTB as true if A and B respectively are not |
| * transposed and set NROWA, NCOLA and NROWB as the number of rows |
| * and columns of A and the number of rows of B respectively. |
| * |
| NOTA = LSAME(TRANSA,'N') |
| NOTB = LSAME(TRANSB,'N') |
| IF (NOTA) THEN |
| NROWA = M |
| NCOLA = K |
| ELSE |
| NROWA = K |
| NCOLA = M |
| END IF |
| IF (NOTB) THEN |
| NROWB = K |
| ELSE |
| NROWB = N |
| END IF |
| * |
| * Test the input parameters. |
| * |
| INFO = 0 |
| IF ((.NOT.NOTA) .AND. (.NOT.LSAME(TRANSA,'C')) .AND. |
| + (.NOT.LSAME(TRANSA,'T'))) THEN |
| INFO = 1 |
| ELSE IF ((.NOT.NOTB) .AND. (.NOT.LSAME(TRANSB,'C')) .AND. |
| + (.NOT.LSAME(TRANSB,'T'))) THEN |
| INFO = 2 |
| ELSE IF (M.LT.0) THEN |
| INFO = 3 |
| ELSE IF (N.LT.0) THEN |
| INFO = 4 |
| ELSE IF (K.LT.0) THEN |
| INFO = 5 |
| ELSE IF (LDA.LT.MAX(1,NROWA)) THEN |
| INFO = 8 |
| ELSE IF (LDB.LT.MAX(1,NROWB)) THEN |
| INFO = 10 |
| ELSE IF (LDC.LT.MAX(1,M)) THEN |
| INFO = 13 |
| END IF |
| IF (INFO.NE.0) THEN |
| CALL XERBLA('SGEMM ',INFO) |
| RETURN |
| END IF |
| * |
| * Quick return if possible. |
| * |
| IF ((M.EQ.0) .OR. (N.EQ.0) .OR. |
| + (((ALPHA.EQ.ZERO).OR. (K.EQ.0)).AND. (BETA.EQ.ONE))) RETURN |
| * |
| * And if alpha.eq.zero. |
| * |
| IF (ALPHA.EQ.ZERO) THEN |
| IF (BETA.EQ.ZERO) THEN |
| DO 20 J = 1,N |
| DO 10 I = 1,M |
| C(I,J) = ZERO |
| 10 CONTINUE |
| 20 CONTINUE |
| ELSE |
| DO 40 J = 1,N |
| DO 30 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 30 CONTINUE |
| 40 CONTINUE |
| END IF |
| RETURN |
| END IF |
| * |
| * Start the operations. |
| * |
| IF (NOTB) THEN |
| IF (NOTA) THEN |
| * |
| * Form C := alpha*A*B + beta*C. |
| * |
| DO 90 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 50 I = 1,M |
| C(I,J) = ZERO |
| 50 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 60 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 60 CONTINUE |
| END IF |
| DO 80 L = 1,K |
| TEMP = ALPHA*B(L,J) |
| DO 70 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 70 CONTINUE |
| 80 CONTINUE |
| 90 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**T*B + beta*C |
| * |
| DO 120 J = 1,N |
| DO 110 I = 1,M |
| TEMP = ZERO |
| DO 100 L = 1,K |
| TEMP = TEMP + A(L,I)*B(L,J) |
| 100 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 110 CONTINUE |
| 120 CONTINUE |
| END IF |
| ELSE |
| IF (NOTA) THEN |
| * |
| * Form C := alpha*A*B**T + beta*C |
| * |
| DO 170 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 130 I = 1,M |
| C(I,J) = ZERO |
| 130 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 140 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 140 CONTINUE |
| END IF |
| DO 160 L = 1,K |
| TEMP = ALPHA*B(J,L) |
| DO 150 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 150 CONTINUE |
| 160 CONTINUE |
| 170 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**T*B**T + beta*C |
| * |
| DO 200 J = 1,N |
| DO 190 I = 1,M |
| TEMP = ZERO |
| DO 180 L = 1,K |
| TEMP = TEMP + A(L,I)*B(J,L) |
| 180 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 190 CONTINUE |
| 200 CONTINUE |
| END IF |
| END IF |
| * |
| RETURN |
| * |
| * End of SGEMM . |
| * |
| END |
| |
| *> \brief \b DGEMM |
| * |
| * =========== DOCUMENTATION =========== |
| * |
| * Online html documentation available at |
| * http://www.netlib.org/lapack/explore-html/ |
| * |
| * Definition: |
| * =========== |
| * |
| * SUBROUTINE DGEMM(TRANSA,TRANSB,M,N,K,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
| * |
| * .. Scalar Arguments .. |
| * DOUBLE PRECISION ALPHA,BETA |
| * INTEGER K,LDA,LDB,LDC,M,N |
| * CHARACTER TRANSA,TRANSB |
| * .. |
| * .. Array Arguments .. |
| * DOUBLE PRECISION A(LDA,*),B(LDB,*),C(LDC,*) |
| * .. |
| * |
| * |
| *> \par Purpose: |
| * ============= |
| *> |
| *> \verbatim |
| *> |
| *> DGEMM performs one of the matrix-matrix operations |
| *> |
| *> C := alpha*op( A )*op( B ) + beta*C, |
| *> |
| *> where op( X ) is one of |
| *> |
| *> op( X ) = X or op( X ) = X**T, |
| *> |
| *> alpha and beta are scalars, and A, B and C are matrices, with op( A ) |
| *> an m by k matrix, op( B ) a k by n matrix and C an m by n matrix. |
| *> \endverbatim |
| * |
| * Arguments: |
| * ========== |
| * |
| *> \param[in] TRANSA |
| *> \verbatim |
| *> TRANSA is CHARACTER*1 |
| *> On entry, TRANSA specifies the form of op( A ) to be used in |
| *> the matrix multiplication as follows: |
| *> |
| *> TRANSA = 'N' or 'n', op( A ) = A. |
| *> |
| *> TRANSA = 'T' or 't', op( A ) = A**T. |
| *> |
| *> TRANSA = 'C' or 'c', op( A ) = A**T. |
| *> \endverbatim |
| *> |
| *> \param[in] TRANSB |
| *> \verbatim |
| *> TRANSB is CHARACTER*1 |
| *> On entry, TRANSB specifies the form of op( B ) to be used in |
| *> the matrix multiplication as follows: |
| *> |
| *> TRANSB = 'N' or 'n', op( B ) = B. |
| *> |
| *> TRANSB = 'T' or 't', op( B ) = B**T. |
| *> |
| *> TRANSB = 'C' or 'c', op( B ) = B**T. |
| *> \endverbatim |
| *> |
| *> \param[in] M |
| *> \verbatim |
| *> M is INTEGER |
| *> On entry, M specifies the number of rows of the matrix |
| *> op( A ) and of the matrix C. M must be at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] N |
| *> \verbatim |
| *> N is INTEGER |
| *> On entry, N specifies the number of columns of the matrix |
| *> op( B ) and the number of columns of the matrix C. N must be |
| *> at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] K |
| *> \verbatim |
| *> K is INTEGER |
| *> On entry, K specifies the number of columns of the matrix |
| *> op( A ) and the number of rows of the matrix op( B ). K must |
| *> be at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] ALPHA |
| *> \verbatim |
| *> ALPHA is DOUBLE PRECISION. |
| *> On entry, ALPHA specifies the scalar alpha. |
| *> \endverbatim |
| *> |
| *> \param[in] A |
| *> \verbatim |
| *> A is DOUBLE PRECISION array, dimension ( LDA, ka ), where ka is |
| *> k when TRANSA = 'N' or 'n', and is m otherwise. |
| *> Before entry with TRANSA = 'N' or 'n', the leading m by k |
| *> part of the array A must contain the matrix A, otherwise |
| *> the leading k by m part of the array A must contain the |
| *> matrix A. |
| *> \endverbatim |
| *> |
| *> \param[in] LDA |
| *> \verbatim |
| *> LDA is INTEGER |
| *> On entry, LDA specifies the first dimension of A as declared |
| *> in the calling (sub) program. When TRANSA = 'N' or 'n' then |
| *> LDA must be at least max( 1, m ), otherwise LDA must be at |
| *> least max( 1, k ). |
| *> \endverbatim |
| *> |
| *> \param[in] B |
| *> \verbatim |
| *> B is DOUBLE PRECISION array, dimension ( LDB, kb ), where kb is |
| *> n when TRANSB = 'N' or 'n', and is k otherwise. |
| *> Before entry with TRANSB = 'N' or 'n', the leading k by n |
| *> part of the array B must contain the matrix B, otherwise |
| *> the leading n by k part of the array B must contain the |
| *> matrix B. |
| *> \endverbatim |
| *> |
| *> \param[in] LDB |
| *> \verbatim |
| *> LDB is INTEGER |
| *> On entry, LDB specifies the first dimension of B as declared |
| *> in the calling (sub) program. When TRANSB = 'N' or 'n' then |
| *> LDB must be at least max( 1, k ), otherwise LDB must be at |
| *> least max( 1, n ). |
| *> \endverbatim |
| *> |
| *> \param[in] BETA |
| *> \verbatim |
| *> BETA is DOUBLE PRECISION. |
| *> On entry, BETA specifies the scalar beta. When BETA is |
| *> supplied as zero then C need not be set on input. |
| *> \endverbatim |
| *> |
| *> \param[in,out] C |
| *> \verbatim |
| *> C is DOUBLE PRECISION array, dimension ( LDC, N ) |
| *> Before entry, the leading m by n part of the array C must |
| *> contain the matrix C, except when beta is zero, in which |
| *> case C need not be set on entry. |
| *> On exit, the array C is overwritten by the m by n matrix |
| *> ( alpha*op( A )*op( B ) + beta*C ). |
| *> \endverbatim |
| *> |
| *> \param[in] LDC |
| *> \verbatim |
| *> LDC is INTEGER |
| *> On entry, LDC specifies the first dimension of C as declared |
| *> in the calling (sub) program. LDC must be at least |
| *> max( 1, m ). |
| *> \endverbatim |
| * |
| * Authors: |
| * ======== |
| * |
| *> \author Univ. of Tennessee |
| *> \author Univ. of California Berkeley |
| *> \author Univ. of Colorado Denver |
| *> \author NAG Ltd. |
| * |
| *> \date December 2016 |
| * |
| *> \ingroup double_blas_level3 |
| * |
| *> \par Further Details: |
| * ===================== |
| *> |
| *> \verbatim |
| *> |
| *> Level 3 Blas routine. |
| *> |
| *> -- Written on 8-February-1989. |
| *> Jack Dongarra, Argonne National Laboratory. |
| *> Iain Duff, AERE Harwell. |
| *> Jeremy Du Croz, Numerical Algorithms Group Ltd. |
| *> Sven Hammarling, Numerical Algorithms Group Ltd. |
| *> \endverbatim |
| *> |
| * ===================================================================== |
| SUBROUTINE DGEMM(TRANSA,TRANSB,M,N,K,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
| * |
| * -- Reference BLAS level3 routine (version 3.7.0) -- |
| * -- Reference BLAS is a software package provided by Univ. of Tennessee, -- |
| * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
| * December 2016 |
| * |
| * .. Scalar Arguments .. |
| DOUBLE PRECISION ALPHA,BETA |
| INTEGER K,LDA,LDB,LDC,M,N |
| CHARACTER TRANSA,TRANSB |
| * .. |
| * .. Array Arguments .. |
| DOUBLE PRECISION A(LDA,*),B(LDB,*),C(LDC,*) |
| * .. |
| * |
| * ===================================================================== |
| * |
| * .. External Functions .. |
| LOGICAL LSAME |
| EXTERNAL LSAME |
| * .. |
| * .. External Subroutines .. |
| EXTERNAL XERBLA |
| * .. |
| * .. Intrinsic Functions .. |
| INTRINSIC MAX |
| * .. |
| * .. Local Scalars .. |
| DOUBLE PRECISION TEMP |
| INTEGER I,INFO,J,L,NCOLA,NROWA,NROWB |
| LOGICAL NOTA,NOTB |
| * .. |
| * .. Parameters .. |
| DOUBLE PRECISION ONE,ZERO |
| PARAMETER (ONE=1.0D+0,ZERO=0.0D+0) |
| * .. |
| * |
| * Set NOTA and NOTB as true if A and B respectively are not |
| * transposed and set NROWA, NCOLA and NROWB as the number of rows |
| * and columns of A and the number of rows of B respectively. |
| * |
| NOTA = LSAME(TRANSA,'N') |
| NOTB = LSAME(TRANSB,'N') |
| IF (NOTA) THEN |
| NROWA = M |
| NCOLA = K |
| ELSE |
| NROWA = K |
| NCOLA = M |
| END IF |
| IF (NOTB) THEN |
| NROWB = K |
| ELSE |
| NROWB = N |
| END IF |
| * |
| * Test the input parameters. |
| * |
| INFO = 0 |
| IF ((.NOT.NOTA) .AND. (.NOT.LSAME(TRANSA,'C')) .AND. |
| + (.NOT.LSAME(TRANSA,'T'))) THEN |
| INFO = 1 |
| ELSE IF ((.NOT.NOTB) .AND. (.NOT.LSAME(TRANSB,'C')) .AND. |
| + (.NOT.LSAME(TRANSB,'T'))) THEN |
| INFO = 2 |
| ELSE IF (M.LT.0) THEN |
| INFO = 3 |
| ELSE IF (N.LT.0) THEN |
| INFO = 4 |
| ELSE IF (K.LT.0) THEN |
| INFO = 5 |
| ELSE IF (LDA.LT.MAX(1,NROWA)) THEN |
| INFO = 8 |
| ELSE IF (LDB.LT.MAX(1,NROWB)) THEN |
| INFO = 10 |
| ELSE IF (LDC.LT.MAX(1,M)) THEN |
| INFO = 13 |
| END IF |
| IF (INFO.NE.0) THEN |
| CALL XERBLA('DGEMM ',INFO) |
| RETURN |
| END IF |
| * |
| * Quick return if possible. |
| * |
| IF ((M.EQ.0) .OR. (N.EQ.0) .OR. |
| + (((ALPHA.EQ.ZERO).OR. (K.EQ.0)).AND. (BETA.EQ.ONE))) RETURN |
| * |
| * And if alpha.eq.zero. |
| * |
| IF (ALPHA.EQ.ZERO) THEN |
| IF (BETA.EQ.ZERO) THEN |
| DO 20 J = 1,N |
| DO 10 I = 1,M |
| C(I,J) = ZERO |
| 10 CONTINUE |
| 20 CONTINUE |
| ELSE |
| DO 40 J = 1,N |
| DO 30 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 30 CONTINUE |
| 40 CONTINUE |
| END IF |
| RETURN |
| END IF |
| * |
| * Start the operations. |
| * |
| IF (NOTB) THEN |
| IF (NOTA) THEN |
| * |
| * Form C := alpha*A*B + beta*C. |
| * |
| DO 90 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 50 I = 1,M |
| C(I,J) = ZERO |
| 50 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 60 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 60 CONTINUE |
| END IF |
| DO 80 L = 1,K |
| TEMP = ALPHA*B(L,J) |
| DO 70 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 70 CONTINUE |
| 80 CONTINUE |
| 90 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**T*B + beta*C |
| * |
| DO 120 J = 1,N |
| DO 110 I = 1,M |
| TEMP = ZERO |
| DO 100 L = 1,K |
| TEMP = TEMP + A(L,I)*B(L,J) |
| 100 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 110 CONTINUE |
| 120 CONTINUE |
| END IF |
| ELSE |
| IF (NOTA) THEN |
| * |
| * Form C := alpha*A*B**T + beta*C |
| * |
| DO 170 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 130 I = 1,M |
| C(I,J) = ZERO |
| 130 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 140 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 140 CONTINUE |
| END IF |
| DO 160 L = 1,K |
| TEMP = ALPHA*B(J,L) |
| DO 150 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 150 CONTINUE |
| 160 CONTINUE |
| 170 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**T*B**T + beta*C |
| * |
| DO 200 J = 1,N |
| DO 190 I = 1,M |
| TEMP = ZERO |
| DO 180 L = 1,K |
| TEMP = TEMP + A(L,I)*B(J,L) |
| 180 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 190 CONTINUE |
| 200 CONTINUE |
| END IF |
| END IF |
| * |
| RETURN |
| * |
| * End of DGEMM . |
| * |
| END |
| |
| *> \brief \b ZGEMM |
| * |
| * =========== DOCUMENTATION =========== |
| * |
| * Online html documentation available at |
| * http://www.netlib.org/lapack/explore-html/ |
| * |
| * Definition: |
| * =========== |
| * |
| * SUBROUTINE ZGEMM(TRANSA,TRANSB,M,N,K,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
| * |
| * .. Scalar Arguments .. |
| * COMPLEX*16 ALPHA,BETA |
| * INTEGER K,LDA,LDB,LDC,M,N |
| * CHARACTER TRANSA,TRANSB |
| * .. |
| * .. Array Arguments .. |
| * COMPLEX*16 A(LDA,*),B(LDB,*),C(LDC,*) |
| * .. |
| * |
| * |
| *> \par Purpose: |
| * ============= |
| *> |
| *> \verbatim |
| *> |
| *> ZGEMM performs one of the matrix-matrix operations |
| *> |
| *> C := alpha*op( A )*op( B ) + beta*C, |
| *> |
| *> where op( X ) is one of |
| *> |
| *> op( X ) = X or op( X ) = X**T or op( X ) = X**H, |
| *> |
| *> alpha and beta are scalars, and A, B and C are matrices, with op( A ) |
| *> an m by k matrix, op( B ) a k by n matrix and C an m by n matrix. |
| *> \endverbatim |
| * |
| * Arguments: |
| * ========== |
| * |
| *> \param[in] TRANSA |
| *> \verbatim |
| *> TRANSA is CHARACTER*1 |
| *> On entry, TRANSA specifies the form of op( A ) to be used in |
| *> the matrix multiplication as follows: |
| *> |
| *> TRANSA = 'N' or 'n', op( A ) = A. |
| *> |
| *> TRANSA = 'T' or 't', op( A ) = A**T. |
| *> |
| *> TRANSA = 'C' or 'c', op( A ) = A**H. |
| *> \endverbatim |
| *> |
| *> \param[in] TRANSB |
| *> \verbatim |
| *> TRANSB is CHARACTER*1 |
| *> On entry, TRANSB specifies the form of op( B ) to be used in |
| *> the matrix multiplication as follows: |
| *> |
| *> TRANSB = 'N' or 'n', op( B ) = B. |
| *> |
| *> TRANSB = 'T' or 't', op( B ) = B**T. |
| *> |
| *> TRANSB = 'C' or 'c', op( B ) = B**H. |
| *> \endverbatim |
| *> |
| *> \param[in] M |
| *> \verbatim |
| *> M is INTEGER |
| *> On entry, M specifies the number of rows of the matrix |
| *> op( A ) and of the matrix C. M must be at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] N |
| *> \verbatim |
| *> N is INTEGER |
| *> On entry, N specifies the number of columns of the matrix |
| *> op( B ) and the number of columns of the matrix C. N must be |
| *> at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] K |
| *> \verbatim |
| *> K is INTEGER |
| *> On entry, K specifies the number of columns of the matrix |
| *> op( A ) and the number of rows of the matrix op( B ). K must |
| *> be at least zero. |
| *> \endverbatim |
| *> |
| *> \param[in] ALPHA |
| *> \verbatim |
| *> ALPHA is COMPLEX*16 |
| *> On entry, ALPHA specifies the scalar alpha. |
| *> \endverbatim |
| *> |
| *> \param[in] A |
| *> \verbatim |
| *> A is COMPLEX*16 array, dimension ( LDA, ka ), where ka is |
| *> k when TRANSA = 'N' or 'n', and is m otherwise. |
| *> Before entry with TRANSA = 'N' or 'n', the leading m by k |
| *> part of the array A must contain the matrix A, otherwise |
| *> the leading k by m part of the array A must contain the |
| *> matrix A. |
| *> \endverbatim |
| *> |
| *> \param[in] LDA |
| *> \verbatim |
| *> LDA is INTEGER |
| *> On entry, LDA specifies the first dimension of A as declared |
| *> in the calling (sub) program. When TRANSA = 'N' or 'n' then |
| *> LDA must be at least max( 1, m ), otherwise LDA must be at |
| *> least max( 1, k ). |
| *> \endverbatim |
| *> |
| *> \param[in] B |
| *> \verbatim |
| *> B is COMPLEX*16 array, dimension ( LDB, kb ), where kb is |
| *> n when TRANSB = 'N' or 'n', and is k otherwise. |
| *> Before entry with TRANSB = 'N' or 'n', the leading k by n |
| *> part of the array B must contain the matrix B, otherwise |
| *> the leading n by k part of the array B must contain the |
| *> matrix B. |
| *> \endverbatim |
| *> |
| *> \param[in] LDB |
| *> \verbatim |
| *> LDB is INTEGER |
| *> On entry, LDB specifies the first dimension of B as declared |
| *> in the calling (sub) program. When TRANSB = 'N' or 'n' then |
| *> LDB must be at least max( 1, k ), otherwise LDB must be at |
| *> least max( 1, n ). |
| *> \endverbatim |
| *> |
| *> \param[in] BETA |
| *> \verbatim |
| *> BETA is COMPLEX*16 |
| *> On entry, BETA specifies the scalar beta. When BETA is |
| *> supplied as zero then C need not be set on input. |
| *> \endverbatim |
| *> |
| *> \param[in,out] C |
| *> \verbatim |
| *> C is COMPLEX*16 array, dimension ( LDC, N ) |
| *> Before entry, the leading m by n part of the array C must |
| *> contain the matrix C, except when beta is zero, in which |
| *> case C need not be set on entry. |
| *> On exit, the array C is overwritten by the m by n matrix |
| *> ( alpha*op( A )*op( B ) + beta*C ). |
| *> \endverbatim |
| *> |
| *> \param[in] LDC |
| *> \verbatim |
| *> LDC is INTEGER |
| *> On entry, LDC specifies the first dimension of C as declared |
| *> in the calling (sub) program. LDC must be at least |
| *> max( 1, m ). |
| *> \endverbatim |
| * |
| * Authors: |
| * ======== |
| * |
| *> \author Univ. of Tennessee |
| *> \author Univ. of California Berkeley |
| *> \author Univ. of Colorado Denver |
| *> \author NAG Ltd. |
| * |
| *> \date December 2016 |
| * |
| *> \ingroup complex16_blas_level3 |
| * |
| *> \par Further Details: |
| * ===================== |
| *> |
| *> \verbatim |
| *> |
| *> Level 3 Blas routine. |
| *> |
| *> -- Written on 8-February-1989. |
| *> Jack Dongarra, Argonne National Laboratory. |
| *> Iain Duff, AERE Harwell. |
| *> Jeremy Du Croz, Numerical Algorithms Group Ltd. |
| *> Sven Hammarling, Numerical Algorithms Group Ltd. |
| *> \endverbatim |
| *> |
| * ===================================================================== |
| SUBROUTINE ZGEMM(TRANSA,TRANSB,M,N,K,ALPHA,A,LDA,B,LDB,BETA,C,LDC) |
| * |
| * -- Reference BLAS level3 routine (version 3.7.0) -- |
| * -- Reference BLAS is a software package provided by Univ. of Tennessee, -- |
| * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..-- |
| * December 2016 |
| * |
| * .. Scalar Arguments .. |
| COMPLEX*16 ALPHA,BETA |
| INTEGER K,LDA,LDB,LDC,M,N |
| CHARACTER TRANSA,TRANSB |
| * .. |
| * .. Array Arguments .. |
| COMPLEX*16 A(LDA,*),B(LDB,*),C(LDC,*) |
| * .. |
| * |
| * ===================================================================== |
| * |
| * .. External Functions .. |
| LOGICAL LSAME |
| EXTERNAL LSAME |
| * .. |
| * .. External Subroutines .. |
| EXTERNAL XERBLA |
| * .. |
| * .. Intrinsic Functions .. |
| INTRINSIC DCONJG,MAX |
| * .. |
| * .. Local Scalars .. |
| COMPLEX*16 TEMP |
| INTEGER I,INFO,J,L,NCOLA,NROWA,NROWB |
| LOGICAL CONJA,CONJB,NOTA,NOTB |
| * .. |
| * .. Parameters .. |
| COMPLEX*16 ONE |
| PARAMETER (ONE= (1.0D+0,0.0D+0)) |
| COMPLEX*16 ZERO |
| PARAMETER (ZERO= (0.0D+0,0.0D+0)) |
| * .. |
| * |
| * Set NOTA and NOTB as true if A and B respectively are not |
| * conjugated or transposed, set CONJA and CONJB as true if A and |
| * B respectively are to be transposed but not conjugated and set |
| * NROWA, NCOLA and NROWB as the number of rows and columns of A |
| * and the number of rows of B respectively. |
| * |
| NOTA = LSAME(TRANSA,'N') |
| NOTB = LSAME(TRANSB,'N') |
| CONJA = LSAME(TRANSA,'C') |
| CONJB = LSAME(TRANSB,'C') |
| IF (NOTA) THEN |
| NROWA = M |
| NCOLA = K |
| ELSE |
| NROWA = K |
| NCOLA = M |
| END IF |
| IF (NOTB) THEN |
| NROWB = K |
| ELSE |
| NROWB = N |
| END IF |
| * |
| * Test the input parameters. |
| * |
| INFO = 0 |
| IF ((.NOT.NOTA) .AND. (.NOT.CONJA) .AND. |
| + (.NOT.LSAME(TRANSA,'T'))) THEN |
| INFO = 1 |
| ELSE IF ((.NOT.NOTB) .AND. (.NOT.CONJB) .AND. |
| + (.NOT.LSAME(TRANSB,'T'))) THEN |
| INFO = 2 |
| ELSE IF (M.LT.0) THEN |
| INFO = 3 |
| ELSE IF (N.LT.0) THEN |
| INFO = 4 |
| ELSE IF (K.LT.0) THEN |
| INFO = 5 |
| ELSE IF (LDA.LT.MAX(1,NROWA)) THEN |
| INFO = 8 |
| ELSE IF (LDB.LT.MAX(1,NROWB)) THEN |
| INFO = 10 |
| ELSE IF (LDC.LT.MAX(1,M)) THEN |
| INFO = 13 |
| END IF |
| IF (INFO.NE.0) THEN |
| CALL XERBLA('ZGEMM ',INFO) |
| RETURN |
| END IF |
| * |
| * Quick return if possible. |
| * |
| IF ((M.EQ.0) .OR. (N.EQ.0) .OR. |
| + (((ALPHA.EQ.ZERO).OR. (K.EQ.0)).AND. (BETA.EQ.ONE))) RETURN |
| * |
| * And when alpha.eq.zero. |
| * |
| IF (ALPHA.EQ.ZERO) THEN |
| IF (BETA.EQ.ZERO) THEN |
| DO 20 J = 1,N |
| DO 10 I = 1,M |
| C(I,J) = ZERO |
| 10 CONTINUE |
| 20 CONTINUE |
| ELSE |
| DO 40 J = 1,N |
| DO 30 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 30 CONTINUE |
| 40 CONTINUE |
| END IF |
| RETURN |
| END IF |
| * |
| * Start the operations. |
| * |
| IF (NOTB) THEN |
| IF (NOTA) THEN |
| * |
| * Form C := alpha*A*B + beta*C. |
| * |
| DO 90 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 50 I = 1,M |
| C(I,J) = ZERO |
| 50 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 60 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 60 CONTINUE |
| END IF |
| DO 80 L = 1,K |
| TEMP = ALPHA*B(L,J) |
| DO 70 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 70 CONTINUE |
| 80 CONTINUE |
| 90 CONTINUE |
| ELSE IF (CONJA) THEN |
| * |
| * Form C := alpha*A**H*B + beta*C. |
| * |
| DO 120 J = 1,N |
| DO 110 I = 1,M |
| TEMP = ZERO |
| DO 100 L = 1,K |
| TEMP = TEMP + DCONJG(A(L,I))*B(L,J) |
| 100 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 110 CONTINUE |
| 120 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**T*B + beta*C |
| * |
| DO 150 J = 1,N |
| DO 140 I = 1,M |
| TEMP = ZERO |
| DO 130 L = 1,K |
| TEMP = TEMP + A(L,I)*B(L,J) |
| 130 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 140 CONTINUE |
| 150 CONTINUE |
| END IF |
| ELSE IF (NOTA) THEN |
| IF (CONJB) THEN |
| * |
| * Form C := alpha*A*B**H + beta*C. |
| * |
| DO 200 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 160 I = 1,M |
| C(I,J) = ZERO |
| 160 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 170 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 170 CONTINUE |
| END IF |
| DO 190 L = 1,K |
| TEMP = ALPHA*DCONJG(B(J,L)) |
| DO 180 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 180 CONTINUE |
| 190 CONTINUE |
| 200 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A*B**T + beta*C |
| * |
| DO 250 J = 1,N |
| IF (BETA.EQ.ZERO) THEN |
| DO 210 I = 1,M |
| C(I,J) = ZERO |
| 210 CONTINUE |
| ELSE IF (BETA.NE.ONE) THEN |
| DO 220 I = 1,M |
| C(I,J) = BETA*C(I,J) |
| 220 CONTINUE |
| END IF |
| DO 240 L = 1,K |
| TEMP = ALPHA*B(J,L) |
| DO 230 I = 1,M |
| C(I,J) = C(I,J) + TEMP*A(I,L) |
| 230 CONTINUE |
| 240 CONTINUE |
| 250 CONTINUE |
| END IF |
| ELSE IF (CONJA) THEN |
| IF (CONJB) THEN |
| * |
| * Form C := alpha*A**H*B**H + beta*C. |
| * |
| DO 280 J = 1,N |
| DO 270 I = 1,M |
| TEMP = ZERO |
| DO 260 L = 1,K |
| TEMP = TEMP + DCONJG(A(L,I))*DCONJG(B(J,L)) |
| 260 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 270 CONTINUE |
| 280 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**H*B**T + beta*C |
| * |
| DO 310 J = 1,N |
| DO 300 I = 1,M |
| TEMP = ZERO |
| DO 290 L = 1,K |
| TEMP = TEMP + DCONJG(A(L,I))*B(J,L) |
| 290 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 300 CONTINUE |
| 310 CONTINUE |
| END IF |
| ELSE |
| IF (CONJB) THEN |
| * |
| * Form C := alpha*A**T*B**H + beta*C |
| * |
| DO 340 J = 1,N |
| DO 330 I = 1,M |
| TEMP = ZERO |
| DO 320 L = 1,K |
| TEMP = TEMP + A(L,I)*DCONJG(B(J,L)) |
| 320 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 330 CONTINUE |
| 340 CONTINUE |
| ELSE |
| * |
| * Form C := alpha*A**T*B**T + beta*C |
| * |
| DO 370 J = 1,N |
| DO 360 I = 1,M |
| TEMP = ZERO |
| DO 350 L = 1,K |
| TEMP = TEMP + A(L,I)*B(J,L) |
| 350 CONTINUE |
| IF (BETA.EQ.ZERO) THEN |
| C(I,J) = ALPHA*TEMP |
| ELSE |
| C(I,J) = ALPHA*TEMP + BETA*C(I,J) |
| END IF |
| 360 CONTINUE |
| 370 CONTINUE |
| END IF |
| END IF |
| * |
| RETURN |
| * |
| * End of ZGEMM . |
| * |
| END |
