gdb/testsuite/gdb.src/pre-commit.exp

# Copyright 2025-2026 Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

# Run the pre-commit hooks.

set repodir $srcdir/../..

if {![file exists $repodir/.git]} {
    unsupported "Not in a git repository"
    return
}

with_cwd $repodir {

    set result [remote_exec build "pre-commit --version"]
    set status [lindex $result 0]
    if {$status != 0} {
	unsupported "pre-commit missing or broken"
	return
    }

    set result [remote_exec build "pre-commit run --files foo/bar.c"]
    set output [lindex $result 1]

    set re \
	{pre-commit version [0-9.]* is required but version [0-9.]* is installed}
    if {[regexp $re $output]} {
	unsupported "pre-commit too old"
	return
    }

    with_test_prefix pre-commit {
	set re {^[a-zA-Z0-9][a-zA-Z0-9_-]+}
	set hook_list [regexp -lineanchor -all -inline $re $output]
	gdb_assert {[llength $hook_list] != 0} "get hooks"

	foreach hook $hook_list {
	    if {$hook == "pre-commit-setup"} {
		# Skip the pre-commit-setup check.  It checks the repository
		# setup, not the sources.
		continue
	    }
	    if {$hook == "check-gnu-style"} {
		# Skip the check-gnu-style check.  It checks patches, not the
		# sources.
		continue
	    }

	    with_test_prefix $hook {
		set result [remote_exec build "pre-commit run $hook --all-files -v"]
		set status [lindex $result 0]
		gdb_assert {$status == 0} "run"
	    }
	}
    }

    with_test_prefix commit-msg {
	set commit_msg [build_standard_output_file "commit-msg.txt"]

	# codespell:ignore-begin.
	gdb_produce_source $commit_msg {
	    This should aways produce a codespell warning.
	}
	# codespell:ignore-end.

	set result \
	    [remote_exec build \
		 "pre-commit run --hook-stage commit-msg --commit-msg-filename $commit_msg -v"]
	set status [lindex $result 0]
	set output [lindex $result 1]
	gdb_assert {$status == 0} "run"

	with_test_prefix codespell-log {
	    # codespell:ignore-begin.
	    set re [string_to_regexp "aways ==> "]
	    # codespell:ignore-end.

	    gdb_assert {[regexp $re $output]} "output"
	}
    }
}