gdb/testsuite/gdb.dwarf2/fission-with-type-unit.exp

# Copyright 2025-2026 Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

# This test is meant to reproduce a bug where having a DWO file with a type unit
# as the first unit would cause an internal error on CU expansion.

load_lib dwarf.exp

# This test can only be run on targets which support DWARF-2 and use gas.
require dwarf2_support

standard_testfile .c -dw.S

set asm_file [standard_output_file $srcfile2]

Dwarf::assemble $asm_file {
    # In the main file.
    cu {
	version 5
	dwo_id 0xF00D
    } {
	compile_unit {
	    DW_AT_dwo_name ${::gdb_test_file_name}-dw.dwo DW_FORM_strp
	} {}
    }

    # In the .dwo file.
    tu {
	fission 1
	version 5
    } 0xCAFE "the_type" {
	type_unit {} {
	    the_type: base_type {
		DW_AT_byte_size 4 DW_FORM_sdata
		DW_AT_encoding  @DW_ATE_signed
		DW_AT_name      int
	    }
	}
    }

    cu {
	fission 1
	version 5
	dwo_id 0xF00D
    } {
	compile_unit {} {
	    declare_labels int4_type

	    int4_type: DW_TAG_base_type {
		DW_AT_byte_size 4 DW_FORM_sdata
		DW_AT_encoding  @DW_ATE_signed
		DW_AT_name      int
	    }

	    DW_TAG_variable {
		DW_AT_name global_var
		DW_AT_type :$int4_type
		DW_AT_location {
		    DW_OP_const1u 12
		    DW_OP_stack_value
		} SPECIAL_expr
	    }
	}
    }
}

set obj [standard_output_file "${testfile}-dw.o"]
if {[build_executable_and_dwo_files "$testfile.exp" "${binfile}" {} \
	 [list $asm_file {nodebug split-dwo} $obj] \
	 [list $srcfile  {nodebug}]]} {
    return
}

clean_restart ${testfile}

# This would cause an internal error.
gdb_test_no_output "maint expand-symtabs"

# Sanity check that the CU was correctly loaded.
gdb_test "print global_var" " = 12"

# Test again just to see if the symbol can be found without having expanded the
# symtab first.
clean_restart ${testfile}
gdb_test "print global_var" " = 12" "print global_var without symtab expansion"