gdb/testsuite/gdb.dwarf2/imported-unit.exp

# Copyright 2019-2026 Free Software Foundation, Inc.

# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

# Import a CU into an "artificial" CU.  For each DW_TAG DIE in the
# artificial CU, use DW_AT_abstract_origin to refer to a DIE in the
# imported CU.  This DWARF file organization is frequently found in
# programs compiled with -flto (and -g) using GCC.
#
# This test reproduces the bug described in BZ 25065 without relying
# on specific compiler versions or use of optimization switches, in
# this case -flto.

require allow_cplus_tests

load_lib dwarf.exp

# This test can only be run on targets which support DWARF-2 and use gas.
require dwarf2_support

standard_testfile .c .S

# ${testfile} is now "implref-struct".  srcfile2 is "implref-struct.S".
set executable ${testfile}
set asm_file [standard_output_file ${srcfile2}]

# We need to know the size of integer and address types in order
# to write some of the debugging info we'd like to generate.
if {[prepare_for_testing "failed to prepare" ${testfile} ${srcfile} {debug c++}]} {
    return
}

# Create the DWARF.
Dwarf::assemble $asm_file {
    declare_labels cu_label main_label doit_label int_label
    declare_labels Foo_label Foo_pointer_type doit_self_label
    declare_labels foo_label Foo_destructor_obj_pointer_label
    declare_labels Foo_constructor_obj_pointer_label
    set int_size [get_sizeof "int" 4]
    set addr_size [get_sizeof "void *" 8]

    cu {} {
	compile_unit {
	    DW_AT_language @DW_LANG_C_plus_plus
	    DW_AT_name "<artificial>"
	} {
	    imported_unit {
		DW_AT_import %$cu_label
	    }
	    subprogram {
		DW_AT_abstract_origin %$main_label
		MACRO_AT_range {main}
	    } {
		subprogram {
		    DW_AT_abstract_origin %$doit_label
		    MACRO_AT_range {doit}
		} {
		    formal_parameter {
			DW_AT_abstract_origin %$doit_self_label
		    }
		}
		DW_TAG_variable {
		    DW_AT_abstract_origin %$foo_label
		    DW_AT_location 4 data1
		}
	    }
	}
    }

    cu {} {
	cu_label: compile_unit {
	    DW_AT_language @DW_LANG_C_plus_plus
	    DW_AT_name "imported_unit.c"
	} {
	    int_label: base_type {
		DW_AT_byte_size $int_size sdata
		DW_AT_encoding @DW_ATE_signed
		DW_AT_name int
	    }

	    main_label: subprogram {
		DW_AT_name main
		DW_AT_type :$int_label
		DW_AT_external 1 flag
	    } {
		Foo_label: class_type {
		    DW_AT_name Foo
		    DW_AT_byte_size 1 sdata
		} {
		    doit_label: subprogram {
			DW_AT_name doit
			DW_AT_type :$int_label
			DW_AT_accessibility 1 DW_FORM_data1
		    } {
			doit_self_label: formal_parameter {
			    DW_AT_name this
			    DW_AT_artificial 1 DW_FORM_flag_present
			    DW_AT_type :$Foo_pointer_type
			}
		    }
		    Foo_pointer_type: pointer_type {
			DW_AT_byte_size $addr_size sdata
			DW_AT_type :$Foo_label
		    }
		}
		foo_label: DW_TAG_variable {
		    DW_AT_name foo
		    DW_AT_type :$Foo_label
		}
	    }
	}
    }
}

if { [prepare_for_testing "failed to prepare" ${testfile} \
	  [list $srcfile $asm_file] {nodebug}] } {
    return
}

gdb_test_no_output "set language c++"

gdb_test "l imported_unit.c:1" \
    "warning: 1\timported_unit.c: No such file or directory"

gdb_test "info source" "\r\nCurrent source file is imported_unit.c\r\n.*" \
    "info source for imported_unit.c"

# Sanity check
gdb_test "ptype main" "= int \\(void\\)"

# Each of these tests caused a segfault prior to fixing BZ 25065.
gdb_test "ptype main::Foo" "= class Foo \{\\s+public:\\s+int doit\\(void\\);\\s+\}"
gdb_test "ptype main::foo" "= class Foo \{\\s+public:\\s+int doit\\(void\\);\\s+\}"