| dnl Process this with autoconf to create configure |
| AC_INIT(fficonfig.h.in) |
| AM_CONFIG_HEADER(fficonfig.h) |
| |
| AC_MSG_WARN(***********************************************************) |
| AC_MSG_WARN(***********************************************************) |
| AC_MSG_WARN(This is beta code. If you're looking for a stable release) |
| AC_MSG_WARN(then use the most recent one - libffi-1.20.) |
| AC_MSG_WARN(***********************************************************) |
| AC_MSG_WARN(***********************************************************) |
| |
| dnl Default to --enable-multilib |
| AC_ARG_ENABLE(multilib, |
| [ --enable-multilib build many library versions (default)], |
| [case "${enableval}" in |
| yes) multilib=yes ;; |
| no) multilib=no ;; |
| *) AC_MSG_ERROR(bad value ${enableval} for multilib option) ;; |
| esac], [multilib=yes])dnl |
| |
| dnl We may get other options which we don't document: |
| dnl --with-target-subdir, --with-multisrctop, --with-multisubdir |
| |
| if test "${srcdir}" = "."; then |
| if test "${with_target_subdir}" != "."; then |
| libffi_basedir="${srcdir}/${with_multisrctop}.." |
| else |
| libffi_basedir="${srcdir}/${with_multisrctop}" |
| fi |
| else |
| libffi_basedir="${srcdir}" |
| fi |
| AC_SUBST(libffi_basedir) |
| |
| AC_CANONICAL_HOST |
| |
| AM_PROG_LIBTOOL |
| |
| AM_INIT_AUTOMAKE(libffi,2.00-beta,no-define) |
| |
| AC_EXEEXT |
| AM_MAINTAINER_MODE |
| |
| AC_PROG_CC |
| AC_PROG_LIBTOOL |
| |
| TARGETDIR="unknown" |
| case "$host" in |
| mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; TARGETDIR=mips;; |
| i*86-*-linux*) TARGET=X86; TARGETDIR=x86;; |
| i*86-*-solaris*) TARGET=X86; TARGETDIR=x86;; |
| i*86-*-beos*) TARGET=X86; TARGETDIR=x86;; |
| i*86-*-freebsd*) TARGET=X86; TARGETDIR=x86;; |
| i*86-*-win32*) TARGET=X86_WIN32; TARGETDIR=x86;; |
| i*86-*-cygwin*) TARGET=X86_WIN32; TARGETDIR=x86;; |
| i*86-*-mingw*) TARGET=X86_WIN32; TARGETDIR=x86;; |
| sparc-sun-4*) TARGET=SPARC; TARGETDIR=sparc;; |
| sparc-sun-*) TARGET=SPARC; TARGETDIR=sparc;; |
| sparc-*-linux*) TARGET=SPARC; TARGETDIR=sparc;; |
| sparc64-*-linux*) TARGET=SPARC; TARGETDIR=sparc;; |
| alpha*-*-linux* | alpha*-*-osf*) TARGET=ALPHA; TARGETDIR=alpha;; |
| ia64*-*-*) TARGET=IA64; TARGETDIR=ia64;; |
| m68k-*-linux*) TARGET=M68K; TARGETDIR=m68k;; |
| powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; TARGETDIR=powerpc;; |
| powerpc-*-beos*) TARGET=POWERPC; TARGETDIR=powerpc;; |
| arm*-*-linux-*) TARGET=ARM; TARGETDIR=arm;; |
| esac |
| |
| if test $TARGETDIR = unknown; then |
| AC_ERROR("libffi has not been ported to $host.") |
| fi |
| |
| AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes) |
| AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno) |
| AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC) |
| AM_CONDITIONAL(X86, test x$TARGET = xX86) |
| AM_CONDITIONAL(X86_WIN32, test x$TARGET = xX86_WIN32) |
| AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA) |
| AM_CONDITIONAL(IA64, test x$TARGET = xIA64) |
| AM_CONDITIONAL(M68K, test x$TARGET = xM68K) |
| AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC) |
| AM_CONDITIONAL(ARM, test x$TARGET = xARM) |
| |
| AC_HEADER_STDC |
| AC_CHECK_FUNCS(memcpy) |
| AC_FUNC_ALLOCA |
| |
| dnl AC_CHECK_SIZEOF(char) |
| AC_CHECK_SIZEOF(short) |
| AC_CHECK_SIZEOF(int) |
| AC_CHECK_SIZEOF(long) |
| AC_CHECK_SIZEOF(long long) |
| AC_CHECK_SIZEOF(float) |
| AC_CHECK_SIZEOF(double) |
| AC_CHECK_SIZEOF(long double) |
| |
| AC_CHECK_SIZEOF(void *) |
| AC_C_BIGENDIAN |
| |
| AC_SUBST(TARGET) |
| AC_SUBST(TARGETDIR) |
| |
| AC_SUBST(SHELL) |
| |
| AC_ARG_ENABLE(debug,[ --enable-debug debugging mode], AC_DEFINE(FFI_DEBUG)) |
| |
| AC_ARG_ENABLE(debug,[ --disable-structs omit code for struct support], AC_DEFINE(FFI_NO_STRUCTS)) |
| |
| AC_ARG_ENABLE(debug,[ --disable-raw-api make the raw api unavailable], AC_DEFINE(FFI_NO_RAW_API)) |
| |
| AC_ARG_ENABLE(purify-safety, |
| [ --enable-purify-safety purify-safe mode], AC_DEFINE(USING_PURIFY)) |
| |
| AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host") |
| |
| if test "${multilib}" = "yes"; then |
| multilib_arg="--enable-multilib" |
| else |
| multilib_arg= |
| fi |
| |
| AC_OUTPUT(include/Makefile include/ffi.h Makefile, |
| [ |
| if test -n "$CONFIG_FILES"; then |
| ac_file=Makefile . ${libffi_basedir}/../config-ml.in |
| fi |
| ], |
| srcdir=${srcdir} |
| host=${host} |
| target=${target} |
| with_multisubdir=${with_multisubdir} |
| ac_configure_args="${multilib_arg} ${ac_configure_args}" |
| CONFIG_SHELL=${CONFIG_SHELL-/bin/sh} |
| libffi_basedir=${libffi_basedir} |
| CC="${CC}" |
| DEFS="$DEFS" |
| test ! -d include && mkdir include |
| test ! -f include/fficonfig.h && cp fficonfig.h include/fficonfig.h |
| if cmp -s fficonfig.h include/fficonfig.h 2>/dev/null; then |
| echo fficonfig.h unchanged |
| else |
| echo Moving fficonfig.h to include/fficonfig.h |
| cp fficonfig.h include/fficonfig.h |
| fi |
| ) |
| |
| # Make target subdirectories if required. |
| test -d src || mkdir src |
| test -d src/${TARGETDIR} || mkdir src/${TARGETDIR} |